// "FreqCounter"のテスト
//      ★1 カウンター停止直前にオーバーフローがあったかどうかの確認
//      ★2 異常オーバーフロー発生の報知
// 出力制御マクロ
#define PB0_H       (PORTB |=  (1 << PB0))      // PB0 D8
#define PB0_L       (PORTB &= ~(1 << PB0))
#define PB1_H       (PORTB |=  (1 << PB1))      // PB1 D9
#define PB1_L       (PORTB &= ~(1 << PB1))
#define PB2_H       (PORTB |=  (1 << PB2))      // PB2 D10
#define PB2_L       (PORTB &= ~(1 << PB2))
#define PB3_H       (PORTB |=  (1 << PB3))      // PB3 D11
#define PB3_L       (PORTB &= ~(1 << PB3))

// "FreqCounter"データ
unsigned long f_freq;
volatile unsigned char f_ready;
volatile unsigned char f_mlt;
volatile unsigned int  f_tics;
volatile unsigned int  f_period;
volatile unsigned int  f_comp;
//  テストデータ
volatile unsigned int  ovf_chk;
volatile unsigned char ovf_on;
/*****  FreqCounter start   *****/
void frqstart(int ms) {
    TIMSK0 &=~(1<<TOIE0);       // disable Timer0  //disable  millis and delay
    delayMicroseconds(50);      // wait if any ints are pending
    f_period=ms;
    if (f_comp ==0) f_comp=1;   // 0 is not allowed in del us
    // hardware counter setup ( refer atmega168.pdf chapter 16-bit counter1)
    TCCR1A=0;                  // reset timer/counter1 control register A
    TCCR1B=0;                  // reset timer/counter1 control register A
    TCNT1=0;                   // counter value = 0
    // set timer/counter1 hardware as counter , counts events on pin T1 ( arduino pin 5)
    // normal mode, wgm10 .. wgm13 = 0
    TCCR1B |=  (1<<CS10) ;// External clock source on T1 pin. Clock on rising edge.
    TCCR1B |=  (1<<CS11) ;
    TCCR1B |=  (1<<CS12) ;
    // timer2 setup / is used for frequency measurement gatetime generation
    TCCR2A=0;
    TCCR2B=0;
    // timer 2 presaler set to 128 / timer 2 clock = 16Mhz / 256 = 62500 Hz
    TCCR2B |=  (1<<CS20) ;
    TCCR2B &= ~(1<<CS21) ;
    TCCR2B |=  (1<<CS22) ;
    //set timer2 to CTC Mode with OCR2A is top counter value
    TCCR2A &= ~(1<<WGM20) ;
    TCCR2A |=  (1<<WGM21) ;
    TCCR2A &= ~(1<<WGM22) ;
    OCR2A = 124;                // CTC divider by 125
    f_ready=0;                  // reset period measure flag
    f_tics=0;                   // reset interrupt counter
    GTCCR = (1<<PSRASY);        // reset presacler counting
    TCNT2=0;                    // timer2=0
    TCNT1=0;                    // Counter1 = 0
    TIMSK2 |=(1<<OCIE2A);       // enable Timer2 Interrupt
                                // External clock source on T1 pin. Clock on rising edge.
    TCCR1B |= (1<<CS12) | (1<<CS11) | (1<<CS10);        //   start counting now     
}
/*****  タイマー2コンペアマッチA割り込み  *****/
//  Timer2 Interrupt Service is invoked by hardware Timer2 every 1ms = 1000 Hz
//  16Mhz / 128 / 125 = 1000 Hz
//  here the gatetime generation for freq. measurement takes place: 
ISR(TIMER2_COMPA_vect) {
    PB1_H;                              // (!!!)
    if(f_tics >= f_period) {             
        delayMicroseconds(f_comp);
        if (TIFR1 & (1<<TOV1)) {        // 停止前にOVFあり?　★1
            PB3_H;                      // (!!!)
            ovf_on  = 1;                // 停止直前OVFあり
            ovf_chk++;                  // 回数+1
        }
        TCCR1B = TCCR1B & ~7;           // Gate Off  / Counter T1 stopped  タイマー1停止
        TIMSK2 &= ~(1<<OCIE2A);         // disable Timer2 Interrupt
        TIMSK0 |=(1<<TOIE0);            // enable Timer0 again // millis and delay
        f_ready=1;                      // set global flag for end count period
        f_freq = 0x10000 * f_mlt;       // mult #overflows by 65636
        f_freq += TCNT1;                 // add counter1 value
        f_mlt=0;
    }
    f_tics++;                   // count number of interrupt events
    if (TIFR1 & (1<<TOV1)) {    // if Timer/Counter 1 overflow flag
        PB2_H;                  // (!!!)
        f_mlt++;                // count number of Counter1 overflows
        TIFR1 = (1<<TOV1);      // clear Timer/Counter 1 overflow flag
    }
    PB3_L;                      // (!!!)
    PB2_L;                      // (!!!)
    PB1_L;                      // (!!!)
}

/*****  SETUP   *****/
void setup()
{
    pinMode(8,  OUTPUT);        // startパルス
    pinMode(9,  OUTPUT);        // OC2A割り込み
    pinMode(10, OUTPUT);        // OVFチェック
    pinMode(11, OUTPUT);        // 停止直前のOVF
    pinMode(5,  INPUT_PULLUP);  // カウントパルス入力
    Serial.begin(115200);       // connect to the serial port
    Serial.println("Frequency Counter TEST-1");
}

/*****  LOOP    *****/
unsigned long frq;
void loop()
{
char s[20];
    f_comp = 10;        // Cal Value / Calibrate with professional Freq Counter
    ovf_on = 0;
    PB0_H;                  // (!!!)
    frqstart(1000);         // 1000 ms Gate Time
    while (f_ready == 0)    // ゲートタイムアップ待ち
    frq = f_freq;                   // 周波数 0.1秒ゲート
    PB0_L;                  // (!!!)
    sprintf(s, "Frq:%8ldHz", frq);
    Serial.print(s);
    if(ovf_on){                 // ★2
        Serial.print(" OVF:");
        Serial.print(ovf_chk);
    }
    Serial.println();
    delay(20);
}